loopxseg
Prev | Orchestra Opcodes and Operators | Next

## loopxseg

loopxseg — Generate control signal consisting of exponential segments delimited by two or more specified points.

## Description

Generate control signal consisting of exponential segments delimited by two or more specified points. The entire envelope is looped at kfreq rate. Each parameter can be varied at k-rate.

## Syntax

    ksig loopxseg kfreq, ktrig, iphase, kvalue0, ktime0  [, kvalue1] [, ktime1] \
          [, kvalue2] [, ktime2] [...]

## Performance

ksig -- Output signal.

kfreq -- Repeat rate in Hz or fraction of Hz.

ktrig -- If non-zero, retriggers the envelope from start (see trigger opcode), before the envelope cycle is completed.

iphase -- A value between 0 and 1 to say where to start the loop. Zero, the commonest value, indicates the beginning.

ktime0...ktimeN -- Times of points; expressed in fraction of a cycle.

kvalue0...kvalueN -- Values of points

loopxseg opcode is similar to expseg, but the entire envelope is looped at kfreq rate. Notice that times are not expressed in seconds but in fraction of a cycle. Actually each duration represent is proportional to the other, and the entire cycle duration is proportional to the sum of all duration values.

The sum of all duration is then rescaled according to kfreq argument. For example, considering an envelope made up of 3 segments, each segment having 100 as duration value, their sum will be 300. This value represents the total duration of the envelope, and is actually divided into 3 equal parts, a part for each segment.

Actually, the real envelope duration in seconds is determined by kfreq. Again, if the envelope is made up of 3 segments, but this time the first and last segments have a duration of 50, whereas the central segment has a duration of 100 again, their sum will be 200. This time 200 represent the total duration of the 3 segments, so the central segment will be twice as long as the other segments.

All parameters can be varied at k-rate. Negative frequency values are allowed, reading the envelope backward. ktime0 should always be set to 0, except if the user wants some special effect.

## Examples

Here is an example of the loopxseg opcode. It uses the file loopxseg.csd.

Example 533. Example of the loopxseg opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac      ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o loopxseg.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1
    kfreq  rspline  0.01,20,0.2,1   ; freq. of loop repetition created by random spline
    ktrig  init     0   ; loop restart trigger (not used)
    iphase =        0   ; initial phase
    ; loop of filter cutoff values (oct format). Rescaled further down.
    kcfoct loopxseg  kfreq, ktrig, iphase, 1,1,0,0
    kenv  linseg   0,0.01,1,p3-5.01,1,5,0
    asig  vco2     0.2*kenv,cpsmidinn(48),0
    kdep  rspline  5,8,0.2,1  ; filter depth created by a random spline
    kcf   port     cpsoct((kcfoct*kdep)+4), 0.001  ; smooth filter changes
    asig  moogladder  asig,kcf,rnd(0.6)
    aL,aR pan2     asig,rnd(1)
          outs     aL, aR
    endin

    </CsInstruments>
    <CsScore>
    i 1  0 60
    e
    </CsScore>
    </CsoundSynthesizer>

## See Also

lpshold loopseg

## Credits

Author: John ffitch

New in Version 5.12

Prev | Up | Next
looptseg | Home | lorenz